Morrowind talk:Mehrunes Dagon's Quest

Wielding the Rusty Dagger

The player must wield "A Rusty Dagger" while communicating with Mehrunes Dagon in order to receive Mehrunes' Razor. Otherwise, the Mehrunes Dagon speech will commence but "A Rusty Dagger" will remain in the player's inventory. -- 24.242.249.196 at 15:51, 23 September 2020 (UTC)

There is no requirement for the player to wield the Rusty Dagger in order to complete this quest normally. I have completed the quest and received Mehrunes' Razor with the Rusty Dagger in inventory, and a check of the script which controls the quest shows that it only checks whether the player is carrying the Rusty Dagger, not whether it is equipped. The script is posted below:

DaedraMehrunes Script

Begin DaedraMehrunes

short talk
short state
short button
short messageOn

if ( OnActivate == 1 )
  set talk to 1
endif

if ( GetJournalIndex "DA_Mehrunes" == 20 )
  if ( Player->GetItemCount "Rusty_Dagger_UNIQUE" > 0 )
    if ( GetDistance Player < 800 )
      Journal "DA_Mehrunes" 30
    endif
  endif
endif

if ( talk == 1 )

  if ( GetJournalIndex "DA_Mehrunes" < 10 )
    if ( State == 0 )
      if ( Player->SayDone == 1 )
        Player->Say "Vo\Misc\DA_MehrunesIntro.wav", "Why do you call on me, little mortal? Do you seek your death so soon? I should crush you where you stand, yet you show mettle by even approaching me. How ambitious are you, little one."
        set state to 10
      endif

    elseif ( State == 10 )
      if ( Player->SayDone == 1 )
        Journal "DA_Mehrunes" 10  ;give journal entry
        MessageBox "Would you like a chance to prove your worth to me?" "I wish to prove my worth." "I have no desire to deal with you, Daedra Prince." ;choice to do quest
          set messageOn to 1
          set talk to 0
          set state to 20
      endif

    endif

  elseif ( GetJournalIndex "DA_Mehrunes" == 30 )
    if ( Player->GetItemCount "Rusty_Dagger_UNIQUE" > 0 )
      if ( Player->SayDone == 1 )
        Player->Say "Vo\Misc\DA_MehrunesComplete.wav","You've found my Razor. Good. Can you feel its hunger? Can you feel its frustration? Now, I will make it again what it once was, what it shall always be. Draw a line of blood across the land in the name of Mehrunes Dagon! "
        player->AddItem "mehrunes'_razor_unique" 1
        player->RemoveItem "Rusty_Dagger_Unique" 1
        MessageBox "Mehrunes' Razor has been added to your inventory."
        Journal "DA_Mehrunes" 40
      endif
    endif
  endif


endif

if ( messageOn == 1)

  set button to GetButtonPressed

  if ( button >= 0 )
    set messageOn to 0
  endif

  if ( button == 0 )            
    if ( Player->SayDone == 1 )
      Player->Say "Vo\Misc\DA_MehrunesChoice1.wav","You are brave or foolish. Perhaps both. This, then, is your chance to prove your courage. My Razor, slayer of man and mer, scourge of all who stand before it, lies dormant. Stolen by an unworthy bearer, an elf of little courage or consequence, it lies unused, gathering dust in the Alas Tomb near Molag Mar. Return it to me, mortal. Prove yourself to be a worthy bearer of Mehrunes' Razor."
      Journal "DA_Mehrunes" 20
    endif               

  elseif ( button == 1 )
    if ( Player->SayDone == 1 )
      Player->Say "Vo\Misc\DA_MehrunesChoice2.wav","I expected little else. Take your leave of this place or die where you stand."
      Journal "DA_Mehrunes" 25
      set button to 0
      ;disable
    endif
  endif

endif

if ( state == 20 )
  set talk to 0
endif

End

The script is attached to the Statue of Mehrunes Dagon in the Yasammidan Shrine and checks whether the player has the Rusty Dagger twice, once to update the Quest stage to 30 (when the player approaches the Statue while carrying the dagger after accepting the quest), and once before activating Mehrunes' final speech completing the quest and replacing the Rusty Dagger with Mehrunes' Razor. In both cases the script uses the GetItemCount function, which only checks whether the player has the Rusty Dagger, regardless of whether it is equipped or not. So I'm curious as to how and why you were able to trigger the final speech yet didn't receive Mehrunes' Razor in place of the Rusty Dagger. That really shouldn't have been possible. Are you running any mods which may have changed this quest?

In any event, I see no need at the moment to post this requirement in the article; given the age of this game, had this requirement existed I'm sure it would have been identified a long time ago, and the quest is definitely doable without needing to wield the Rusty Dagger. Further input on this seemingly anomalous case is welcomed. — Wolfborn↝^(Howl) 03:30, 24 September 2020 (UTC)